Home » パワーポイントマクロ・PowerPoint VBAの使い方 » Shapesコレクション・Shapeオブジェクト » 選択されている図形と同じ形状の図形をすべて選択するパワポマクロ

選択されている図形と同じ形状の図形をすべて選択するパワポマクロ

対象：PowerPoint2007, PowerPoint2010, PowerPoint2013

PowerPointで資料を作成しているときに、同じ形状の図形だけをすべて選択したい、ということが頻繁にありました。

あまりに頻繁に発生するので、アクティブなスライド上に存在する、同じ形状の図形だけをすべて選択するマクロを作成しましたので、ご紹介しておきます。

［スポンサードリンク］

アクティブスライドで選択されている図形と同じ形の図形をすべて選択するサンプルマクロ

さまざまな形状の図形が存在するスライドで、図形を一つ選択しておいて以下のマクロを実行すると、その選択されていた図形と同じ形状の図形だけをすべて選択することができます。

Sub 選択図形と同じ図形だけを選択する()
　On Error GoTo ErrHandl
　
　With ActiveWindow.Selection
　　If .Type <> ppSelectionShapes Then Err.Raise 999
　　If .ShapeRange.Count <> 1 Then Err.Raise 999
　
　　Dim typ As MsoAutoShapeType
　　typ = .ShapeRange.AutoShapeType

　　Dim shp As Shape
　　For Each shp In .SlideRange.Shapes
　　　If shp.AutoShapeType = typ Then
　　　　shp.Select Replace:=msoFalse
　　　End If
　　Next shp
　End With
　
　Exit Sub
　
ErrHandl:
　Select Case Err.Number
　　Case 999
　　　MsgBox "アクティブスライド上で、図形を1つだけ選択してから実行してください。"
　　Case Else
　　　MsgBox Err.Description & vbCrLf & Err.Number
　End Select
　Err.Clear
End Sub

サンプルマクロの解説

選択されている図形のAutoShapeTypeプロパティを、変数typに格納しておいてから、
　　Dim typ As MsoAutoShapeType
　　typ = .ShapeRange.AutoShapeType

アクティブスライド上の全図形に対するFor Each～Nextループの中で、
　　Dim shp As Shape
　　For Each shp In .SlideRange.Shapes

各ShapeのAutoShapeTypeと比較して合致したら、
　　　If shp.AutoShapeType = typ Then

選択を行っています。
　　　　shp.Select Replace:=msoFalse

図形が選択されていないときや、
　　If .Type <> ppSelectionShapes Then Err.Raise 999
複数の図形が選択されているときには、
　　If .ShapeRange.Count <> 1 Then Err.Raise 999

メッセージを表示します。
　ErrHandl:
　　Select Case Err.Number
　　　Case 999
　　　MsgBox "アクティブスライド上で、図形を1つだけ選択してから実行してください。"

最終更新日時：2018-10-22 18:59

▼『いちばんやさしい PowerPoint VBA の教本』は、一番易しいパワポマクロ入門書、というわけではありませんので、ご注意ください。
いちばんやさしいPowerPoint VBAの教本
［スポンサードリンク］

Home » パワーポイントマクロ・PowerPoint VBAの使い方 » Shapesコレクション・Shapeオブジェクト » 選択されている図形と同じ形状の図形をすべて選択するパワポマクロ

『インストラクターのネタ帳』では、2003年10月からMicrosoft Officeの使い方などを紹介し続けています。
日経BP社から出版された、Excel VBAユーザー向けのPython超入門書です↓↓ 上記の『Excel VBAユーザーのためのPythonプログラミング』の、元になったキンドル本です↓↓ 『インストラクターのネタ帳』を運営する伊藤潔人が、初めて書かせていただいた書籍です↓↓ PowerPoint VBA本は、実はオブジェクトブラウザーの使い方を徹底的に解説した本です↓↓ 数式を使った条件付き書式設定が苦手な方に向けたKindle本を書きました↓↓ 小数とPythonのdecimalモジュールの基本をキンドル本としてまとめました↓↓ Pythonの文字列フォーマットの基本をキンドル本としてまとめました↓↓ Excel VBAの経験がある方を対象に、Word VBAの基本をキンドル本としてまとめました↓↓ Excel VBAユーザーの方を対象として、Wordの表をVBAで操作する基礎をまとめました↓↓ 図形を操作するExcel VBAの基本を解説したキンドル本を出しました↓↓ グラフを操作するExcel VBAの基本を解説したキンドル本です↓↓ Pythonの外部ライブラリOpenPyXL（オープンパイエクセル）の入門書を、Excel VBAユーザーに向けに書きました↓↓


「Shapesコレクション・Shapeオブジェクト」の記事一覧

検索


Copyright © インストラクターのネタ帳 All Rights Reserved.

.