Home » パワーポイントマクロ・PowerPoint VBAの使い方 » Shapesコレクション・Shapeオブジェクト » ShapeRangeのAlingnメソッドで図形を中央に配置するパワポマクロ

ShapeRangeのAlingnメソッドで図形を中央に配置するパワポマクロ

対象：PowerPoint2003, PowerPoint2007, PowerPoint2010, PowerPoint2013

Shapeをスライドの中央に配置するPowerPointマクロをご紹介したところ、Microsoft MVPのきぬあささんから
「ShapeRangeのAlignメソッドを使っていないのは何か理由が！」
というツッコミをいただきました。

［スポンサードリンク］

ありがとうございます！！
完全に失念していました（汗）

何かを中央に配置する

何かを中央に配置したい、という要望は、いろいろな場面でいただきます。

前回の記事は、PowerPointの画像をスライドの中央に配置したいという要望がキッカケだったわけですが、その他の物でも、中央に配置したいという要望をよくいただきます。

例えば、
「ブラウザを最大化しないで開いて画面の中央に配置したい」
というのが、昔よくいただいた、中央に配置したい要望の代表例です。

こんな要望をいただいたときに、全体のサイズを半分にした値から、中央に配置したいもののサイズを半分にした値を引き算して、得られた値を、左上の位置指定に利用する、というのはどんな場合でも使える定番の処理です。

この考え方が、
「パワーポイントマクロ画像中央」
という検索キーワードを見たときに、私の頭の中には真っ先に浮かんだため、他の可能性を一切考えずに、前回の記事を書きました。

ShapeRangeオブジェクトのAlignメソッドで中央に配置するサンプルマクロ

きぬあささんのご指摘どおり、PowerPointでShapeをスライドの中央に配置するという目的であれば、ShapeRangeオブジェクトのAlignメソッドを利用するほうが、シンプルなコードになります。

Sub AlingメソッドでアクティブなShapeをスライドの中央に配置する()

　Dim msg As String

　With ActiveWindow.Selection

　　''Shapeが選択されていない場合はマクロを終了
　　If .Type = ppSelectionNone _
　　Or .Type = ppSelectionSlides Then
　　　msg = "中央に配置したいShapeを選択してください。"
　　　MsgBox msg
　　　Exit Sub
　　End If

　　With .ShapeRange
　　　''左右中央に配置
　　　.Align _
　　　　AlignCmd:=msoAlignCenters, _
　　　　RelativeTo:=msoTrue
　　　''上下中央に配置
　　　.Align _
　　　　AlignCmd:=msoAlignMiddles, _
　　　　RelativeTo:=msoTrue
　　End With

　End With

End Sub

ShapeRangeオブジェクトのRangeメソッドの引数を、
　　　AlignCmd:=msoAlignCenters, _
　　　RelativeTo:=msoTrue
と指定することで、そのShapeRangeはスライドの左右中央に配置され、

同じくShapeRangeオブジェクトのRangeメソッドの引数を、
　　　AlignCmd:=msoAlignMiddles, _
　　　RelativeTo:=msoTrue
と指定することで、そのShapeRangeはスライドの上下方向の中央に配置されます。

ShapeRange.Alignの引数・AlignCmdでShapeRangeをどう配置するのかを指定し、引数・RelativeTo:=msoTrueでスライドの端からを基準にしています。

ShapeRangeのAlingnメソッドで図形を中央に配置するパワポマクロ

第1引数については、AlignCmdという名前がイマイチであること、指定する定数msoAlignCenters・msoAlignMiddlesなどから引数の意味がわかることから、名前付き引数を使わないほうがいいと感じるのですが、、第2引数・RelativeToのほうは名前付き引数にしておかないとmsoTrueだけでは意味がわからなくなってしまうため、なんだかモヤモヤした気持ちを抱えつつ、ここでは名前付き引数を使ったコードにしています。