Home » エクセルマクロ・Excel VBAの使い方 » マクロのサンプル » RGB色見本を作成するExcelマクロ

RGB色見本を作成するExcelマクロ

対象：Excel2007, Excel2010, Excel2013, Windows版Excel2016

「excel vba rgb一覧」
「エクセルvba rgb一覧」
といった検索で、このサイト・インストラクターのネタ帳へのアクセスが、時折あります。

何を探していらしたのか、判断に迷う検索キーワードです。

アクセスログを「rgb」という語句に注目して眺めていると、
「excel2010 vba rgb色見本」
「excelマクロ色見本 rgb」
といった検索キーワードもありますので、RGB色見本を作成するExcelマクロを作ってみました。

［スポンサードリンク］

RGB色見本を作成するサンプルマクロ

以下のマクロを実行すると、アクティブなワークシートに、WebセーフカラーのRGB値と色見本が作成されます。

Sub RGB値色見本作成()

　Dim rr As Long, gg As Long, bb As Long
　Dim r As Long: r = 1　' 行番号
　Dim c As Long: c = 1　' 列番号

　For rr = 0 To 255 Step 51
　　For gg = 0 To 255 Step 51
　　　For bb = 0 To 255 Step 51
　　　　With Cells(r, c)
　　　　　.Interior.Color = RGB(rr, gg, bb)
　　　　　.Value = "#" & _
　　　　　　Format(Hex(rr), "00") & _
　　　　　　Format(Hex(gg), "00") & _
　　　　　　Format(Hex(bb), "00")
　　　　End With
　　　　r = r + 1
　　　Next bb
　　　r = r - 6
　　　c = c + 1
　　Next gg
　　r = r + 6
　　c = c - 6
　Next rr

　Columns("A:F").AutoFit

End Sub

サンプルマクロの解説

Webセーフカラーの色見本を作成するマクロですから、R・G・Bの値をそれぞれ16進数で「00」「33」「66」「99」「CC」「FF」と変化させるために、「0」から「255」まで、増分値「51」で3重のFor～Nextループを回して、
　　For rr = 0 To 255 Step 51
　　　For gg = 0 To 255 Step 51
　　　　For bb = 0 To 255 Step 51

Rangeオブジェクトの、InteriorオブジェクトのColorプロパティにRGB値を設定することで、塗りつぶし色を変更して、
　　　　With Cells(r, c)
　　　　　.Interior.Color = RGB(rr, gg, bb)

16進トリプレット表記で値を書き込んで、
　　　　　.Value = "#" & _
　　　　　　Format(Hex(rr), "00") & _
　　　　　　Format(Hex(gg), "00") & _
　　　　　　Format(Hex(bb), "00")

Cellsプロパティに指定する行番号用変数・rと、列番号用変数・cの値を変更しています。
　　　　　r = r + 1
　　　　Next bb
　　　　r = r - 6
　　　　c = c + 1
　　　Next gg
　　　r = r + 6
　　　c = c - 6
　　Next rr