Home » Excel VBA Rangeオブジェクト » コメント » VBAでコメント挿入時にフォントサイズを指定する

VBAでコメント挿入時にフォントサイズを指定する

対象：Excel2010, Excel2013, Windows版Excel2016

「excel addcomment 文字サイズ変更」
「マクロ addcomment の文字を大きく」
といった検索キーワードによるアクセスがあります。

Excel VBAで、AddCommentメソッドを使ってコメントを追加する際に、

フォントサイズを指定するにはどうすればいいのかを探していらしたのでしょう。

［スポンサードリンク］

オブジェクト変数を使ってコメント挿入時にフォントサイズを指定するサンプルマクロ

以下のSubプロシージャを実行すると、アクティブセルに「コメントのサンプル」というコメントが挿入されて、フォントサイズが16ポイントに指定されます。

Sub コメントのフォントサイズを変更する_オブジェクト変数()
　Dim cmt As Comment

　Set cmt = ActiveCell.AddComment("コメントのサンプル")
　cmt.Shape.TextFrame.Characters.Font.Size = 16
End Sub

Range.AddCommentメソッドは、コメントを挿入して、挿入されたコメントを表すCommentオブジェクトを返します。

VBAでコメント挿入時にフォントサイズを指定する

返されたCommentオブジェクトを、オブジェクト変数にセットして、
　　Set cmt = ActiveCell.AddComment("コメントのサンプル")

フォントサイズを指定しています。
　　cmt.Shape.TextFrame.Characters.Font.Size = 16

コメントの実体は、図形（Shapeオブジェクト）なので、Excel VBAでShape内文字列を操作する場合におなじみの、TextFrameオブジェクトの、Charactersオブジェクトの、Fontオブジェクトを取得して、Sizeプロパティでフォントサイズを設定しています。

With文を使ってコメント挿入時にフォントサイズを指定するサンプルマクロ

オブジェクト変数を使わず、Withステートメントを利用するなら、以下のとおりです。

Sub コメントのフォントサイズを変更する_With()
　With ActiveCell.AddComment("コメントのサンプル")
　　.Shape.TextFrame.Characters.Font.Size = 16
　End With
End Sub

マクロ記録でできるコードを流用してオブジェクト変数を使ってコメント挿入時にフォントサイズを指定するサンプルマクロ

コメントの挿入操作をマクロ記録して作られるコードを流用するなら、以下のようなSubプロシージャです。

Sub コメントのフォントサイズを変更する_オブジェクト変数2()
　Dim cmt As Comment

　Set cmt = ActiveCell.AddComment
　cmt.Text "コメントのサンプル"
　cmt.Shape.TextFrame.Characters.Font.Size = 16
End Sub

先ほどのオブジェクト変数を使ったプロシージャでは、
　　Set cmt = ActiveCell.AddComment("コメントのサンプル")
とRange.AddCommentメソッドの引き数で、コメント文字列を指定していますが、このマクロ記録で作れるコードを利用しているマクロでは
　　Set cmt = ActiveCell.AddComment
　　cmt.Text "コメントのサンプル"
と、空のコメントを挿入して、あとからCommentオブジェクトのTextメソッドでコメントを追加しています。